blob: 56f4777d814841d06da11af836bda6fbc70b20e1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Saiem Saeed <saiem.saeed7 at gmail dot com>
pkgname=sayall-bin
pkgver=0.1.0
pkgrel=1
pkgdesc='Wayland voice dictation daemon and recording HUD (prebuilt)'
arch=('x86_64')
url='https://github.com/saiemsaeed/sayall'
license=('MIT')
depends=(
'ca-certificates'
'gcc-libs'
'glibc'
'gtk4'
'gtk4-layer-shell'
'libnotify'
'pipewire-audio'
'wl-clipboard'
'wtype'
)
provides=("sayall=$pkgver")
conflicts=('sayall' 'sayall-git')
options=('!debug')
install='sayall-bin.install'
source=("$pkgname-$pkgver.tar.gz::$url/releases/download/v$pkgver/sayall-$pkgver-linux-x86_64.tar.gz")
sha256sums=('6286e280a6f2d076ab45660bdc994b7888cd2e9e84554d606dffdd9be900d007')
package() {
local src="$srcdir/sayall-$pkgver-linux-x86_64"
install -Dm755 -t "$pkgdir/usr/bin" \
"$src/bin/sayall" \
"$src/bin/sayall-hud"
install -Dm644 -t "$pkgdir/usr/lib/systemd/user" \
"$src/share/systemd/user/sayall.service" \
"$src/share/systemd/user/sayall-hud.service"
sed -i 's|%h/.local/bin/|/usr/bin/|g' \
"$pkgdir/usr/lib/systemd/user/sayall.service" \
"$pkgdir/usr/lib/systemd/user/sayall-hud.service"
install -Dm644 -t "$pkgdir/usr/share/doc/sayall" \
"$src/share/doc/sayall/README.md" \
"$src/share/doc/sayall/CHANGELOG.md"
install -Dm644 -t "$pkgdir/usr/share/licenses/$pkgname" \
"$src/share/licenses/sayall/"*
}
|