blob: 338734c38359bad8ebd1f7a7f2dec1d147aba33e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
|
# Maintainer: galister <galister-dev at pm dot me>
pkgname=wayvr
pkgver=26.7.1
pkgrel=2
pkgdesc="Your way to enjoy VR on Linux! Access your Wayland/X11 desktop from SteamVR/Monado (OpenVR+OpenXR support)"
url="https://github.com/wayvr-org/wayvr"
arch=('x86_64')
license=('GPL-3.0-or-later')
depends=(glibc
libxkbcommon
libxkbcommon-x11
hicolor-icon-theme
libx11
libstdc++
libxcb
openssl
libxext
libxrandr
libgcc
dbus
libpipewire
alsa-lib
openxr
openvr
dav1d
xwayland-satellite)
makedepends=(git
cargo
python3
cmake
clang
shaderc
vulkan-headers)
replaces=("wlx-overlay-s")
conflicts=("$pkgname")
provides=("$pkgname")
source=("$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=("f0bd28664ae06f76c29c985726885caf94164e5e503dd3dfb14d74cb046339d6")
options=(!lto)
# Use debug
export CARGO_PROFILE_RELEASE_DEBUG=2
export CMAKE_POLICY_VERSION_MINIMUM=3.5
export SHADERC_LIB_DIR=/usr/lib
prepare() {
cd "$pkgname-$pkgver"
cd "$pkgname"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
cd "../${pkgname}ctl"
cargo fetch --locked --target "$(rustc -vV | sed -n 's/host: //p')"
}
build() {
cd "$pkgname-$pkgver"
cd "$pkgname"
cargo build --frozen --release --all-features
cd "../${pkgname}ctl"
cargo build --frozen --release --all-features
}
package() {
cd "$pkgname-$pkgver"
install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/$pkgname"
install -Dm0755 -t "$pkgdir/usr/bin/" "target/release/${pkgname}ctl"
cd "$pkgname"
install -Dm0644 -t "$pkgdir/usr/share/applications/" "$pkgname.desktop"
install -Dm0644 -t "$pkgdir/usr/share/icons/hicolor/128x128/apps/" "$pkgname.png"
install -Dm0644 -t "$pkgdir/usr/share/icons/hicolor/scalable/apps/" "$pkgname.svg"
}
|